Inicio › Documentación › Construir estrategias
Herramienta

Lenguaje AQL & Editor

Se abre desde Estrategias → Editor de código AQL…. Resuelve un problema concreto: sin él, una estrategia solo se definiría a través de las combinaciones del Testeo Masivo (que es un espacio de búsqueda, ambiguo por diseño). El código AQL es la escritura textual de una estrategia concreta — inequívoca y reproducible — que el editor convierte directamente en algo testeable.

Un vistazo

Name:       Cruce SMA + RSI
Market:     @ES
Direction:  long

Entry:
    SMA(Close, 50) crosses above SMA(Close, 200)
    and RSI(Close, 14) > 50

Exit:
    RSI(Close, 14) > 70

TakeProfit: 3%
StopLoss:   2 x ATR

El editor colorea con esta misma paleta: palabras clave, indicadores, fuentes, números, operadores.

Estructura

  • Name: nombre libre de la estrategia.
  • Market:/ Timeframe: / Generator: de dónde sale la estrategia (opcional): el mercado, el marco temporal y la herramienta que la encontró. No cambian la regla; al abrir el fichero, el editor se pone en ese mercado.
  • Direction:long / short (dirección por defecto).
  • Entry:condiciones unidas por and. Repetible = OR; con long/short mezcla direcciones.
  • Exit: condiciones de salida (opcional, repetible = OR).
  • TakeProfit:/ StopLoss: objetivos.
  • Series:otros mercados que lee la estrategia (opcional; ver Series de referencia, más abajo).

Comentarios. De una línea: // o # hasta el final de la línea. De párrafo, en varias líneas: entre llaves { … }, como en Delphi, o entre /* … */. Pueden ir en cualquier sitio, incluso en mitad de una condición (CCI(7) < { sobreventa } -100), y sirven para desactivar un bloque entero sin borrarlo.

Mayúsculas. AniQuant escribe las secciones con la inicial en mayúscula (Name, Entry, TakeProfit…), pero el lector no distingue mayúsculas: los ficheros de antes, en minúscula, se siguen leyendo igual. Si el Market es un mercado de datos barajados (AQ Market Shuffle), la línea lleva el comentario # DATOS BARAJADOS: no operar y la ventana de exportación lo avisa con una franja roja.

Indicadores y operandos

  • →Con fuente: SMA(Close, 50)
  • →Sin fuente: ATR(14)
  • →Serie de precio: Close[5] (hace 5 barras)
  • →Patrones sin paréntesis: BullishEngulfing
  • →Desplazamiento: SMA(Close,20)[1]

Una condición compara dos cosas: un indicador con otro o con un número. También puede hacer cuentas con ellos (ver Fórmulas, más abajo). Y la estrategia puede entrar con una orden Stop o Limit en vez de a mercado (ver Órdenes de entrada).

Operadores

> < = >= <= <> crosses above crosses below

>= / <= incluyen el valor límite; <> es «distinto de». Para DayOfYear y demás filtros de calendario, DayOfYear >= 72 and DayOfYear <= 77 selecciona la ventana de días 72 a 77 (ambos incluidos).

Take Profit / Stop Loss

  • →Porcentaje: 3%
  • →Importe: $1.5
  • →Múltiplo de ATR: 2 x ATR. Es el ATR de la barra anterior: el de la barra en curso incluiría su propio rango, que aún no se conoce cuando el precio toca el nivel. Lo mismo para el break-even.
  • →Sin objetivo: none

El período de ATR en TP/SL se ignora (usa el global).

Varias entradas · OR de bloques y reversión long+short

Repite Entry: para unir bloques con OR: la estrategia entra si se cumple cualquiera de los bloques (cada bloque es un and interno). Lo mismo con Exit: repetido. Un bloque a secas hereda el direction: de la estrategia.

Añade una dirección al bloque — Entry long: / Entry short: — para mezclar largos y cortos en una sola estrategia. Cuando dispara un bloque de dirección opuesta a la posición abierta, ésta se da la vuelta: cierra y abre la contraria en la misma barra (vender y comprar el mismo día).

Direction:   long

Entry long:   DayOfYear >= 48 and DayOfYear <= 54
Entry short:  DayOfYear >= 55 and DayOfYear <= 58

Exit:         DayOfYear >= 59 and DayOfYear <= 63

La salida son solo los huecos flat entre ventanas: entre una ventana larga y una corta pegadas no hay salida, la reversión la dispara el bloque opuesto. El Optimizador Estacional genera esto automáticamente al enviar un plan long+short al Portafolio — una estrategia, exportable con reversión a EasyLanguage (TradeStation), MQL5 (MetaTrader 5) y ProRealTime.

Series de referencia: leer otro mercado

Una condición puede leer otro mercado distinto del que operas: el VIX para filtrar el S&P 500, el bono para el oro, el Nasdaq para el Dow… Las órdenes se dan siempre en la serie principal (la del símbolo elegido); la otra serie solo se lee. Se declara en un bloque Series: con un nombre para cada serie, y se usa con el sufijo of.

Ejemplo completo: el sistema CCI-710 (comprar el rebote del CCI de 7 en sobreventa, con la media de 200 subiendo, y salir a las 10 barras) operado solo con el VIX bajo y bajando:

Name:       CCI-710 con VIX
Direction:  long

Series:
    vix = "$VIX"

Entry long:
    CCI(7)[1] < -100
    and CCI(7) > CCI(7)[1]
    and SMA(Close,200) > SMA(Close,200)[5]
    and Close of vix < 20
    and SMA(Close,5) of vix < SMA(Close,5)[1] of vix

Exit:
    BarsSinceEntry >= 10

Las tres primeras condiciones son el CCI-710 de siempre; las dos últimas leen el VIX: su cierre por debajo de 20 y su media de 5 sesiones por debajo de la de ayer (el miedo, bajo y cediendo).

El bloque series:

Una línea por serie: alias = "SIMBOLO", con el símbolo entre comillas. Opcionalmente, su timeframe: vix = "$VIX" @D1. Sin timeframe, se usan las barras de esa serie tal como están guardadas.

El sufijo of

Va detrás del término entero: Close of vix, SMA(Close,5)[1] of vix. También se puede escribir el símbolo directamente, sin declararlo: Close of "$VIX" < 20.

El [n] cuenta barras de ESA serie

SMA(Close,5)[1] of vix es la media del VIX de ayer, aunque operes el ES en barras de 5 minutos. No hay que hacer cuentas de cuántas barras intradía caben en un día.

Solo barras ya cerradas

Nunca se mira al futuro: cada barra ve la última barra de la otra serie que ya había cerrado. El VIX del día (cierra a las 22:15, hora española) vale para el ES diario de ese día, pero no para una barra intradía de antes de las 22:15: esa ve el VIX de ayer.

NewDay

Verdadero en la primera barra de un día nuevo (el Date <> Date[1] de TradeStation). Útil en intradía para actuar una sola vez al día, justo cuando entra el dato diario de la otra serie.

El símbolo tiene que existir

La serie se busca en el Quote Manager por su símbolo. Para el ejemplo: exporta $VIX.X de TradeStation, impórtalo y dalo de alta con el símbolo $VIX. Mientras la otra serie no tenga datos (al principio del histórico), la estrategia no opera.

✓ Revisar avisa con claridad: serie no declarada, símbolo sin ficha en el Quote Manager, símbolo sin comillas, serie declarada que no se usa, dos timeframes en el mismo término…
➜ Una estrategia con series se puede Probar, enviar al Portafolio (y desde allí a Supervivencia, Walk-Forward, Performance…), optimizar en el Laboratorio y exportar (ver Exportar). La serie viaja guardada con la estrategia y forma parte de su identidad.
⚠️ Los barridos del Laboratorio y de Génesis con condiciones sobre otra serie u otro timeframe van por CPU: más lentos, pero correctos.

Fórmulas: cuentas, Define y Count

Una condición puede hacer cuentas con los indicadores y los precios: sumar, restar, multiplicar, dividir, contar barras, buscar el máximo de una fórmula… Sin aprender un lenguaje de programación y sin perder nada de lo que ya hace AniQuant: la estrategia se prueba igual, va a la GPU y se exporta sola a las 6 plataformas.

Ejemplo: comprar una barra de rango muy amplio, con cuerpo grande, tras una racha alcista, y que sea la de mayor rango de las últimas 20:

Name:       Barra de rango amplio
Direction:  long

Define rango  = High - Low
Define cuerpo = Abs(Close - Open)

Entry:
    rango > 2 * ATR(14)
    and cuerpo > 0.6 * rango
    and Count(Close > Open, 10) >= 7
    and Highest(rango, 20)[1] < rango

Exit:
    BarsSinceEntry >= 5

La tercera condición pide que 7 de las 10 últimas barras hayan cerrado por encima de su apertura; la cuarta, que el rango de hoy supere el mayor de las 20 barras anteriores.

Cuentas

+ - * / y paréntesis, con el orden de siempre (primero * y /). Y tres funciones: Abs(x) (valor absoluto), Min(a, b) y Max(a, b). Ejemplo: (Close - Low) / (High - Low) > 0.7, el cierre en el 30 % alto de la barra.

Define: fórmulas con nombre

Una por línea, sin dos puntos: Define rango = High - Low. Un Define puede usar los anteriores. Es un atajo para no repetir la fórmula y leerla mejor: no guarda nada de una barra a otra (no es una variable de EasyLanguage) y la estrategia es la misma que escribiendo la fórmula entera.

Count y Sum

Count(condición, N): cuántas de las últimas N barras (incluida la actual) cumplen la condición. Sum(x, N): la suma de las últimas N barras, por ejemplo Sum(Close - Close[1], 5) < 0. N es un número entero de barras.

Highest, Lowest y SMA de una fórmula

Los de siempre aceptan ahora una fórmula en lugar de un precio: Highest(High - Low, 20), SMA(Close - Open, 3), Lowest(RSI(Close, 14), 10). Con un precio solo (Highest(High, 20)) son exactamente los de antes.

El [n], en cualquier sitio

Detrás de un paréntesis, de una función o de un Define: (High - Low)[1], rango[1], Count(Close > Open, 5)[1]. Y los cruces también valen con fórmulas: SMA(Close - Open, 3) crosses above 0.

and, or y not entre paréntesis

Dentro de un paréntesis se pueden combinar condiciones: (Close > Open or Close > Close[1]), not (Close < SMA(Close, 50)). Entre líneas de un bloque sigue mandando el and.

⚠️ Si algo no se puede calcular, la condición es falsa en esa barra: una división por cero, o un indicador que todavía no tiene datos. Es la misma regla en el motor, en la GPU y en las 6 exportaciones.
✓ Revisar avisa si una condición no compara nada (High - Low a secas), si Count recibe un número en vez de una condición, si un Define no existe o usa uno que se declara después…
➜ Exportar: la fórmula se traduce sola a EasyLanguage, MQL5, ProRealTime, AmiBroker, Pine y NinjaTrader. Lo que mira hacia atrás (los [n], los cruces, Count, Sum…) se guarda en variables aqf1, aqf2… En MetaTrader 5 y NinjaTrader las fórmulas empiezan a valer cuando han pasado unas barras desde que pones la estrategia (las de la ventana más larga).
💡 Las fórmulas las escribes tú: en el editor o como fila de Código AQL en el Laboratorio. Los generadores (Laboratorio, Génesis) no las inventan por su cuenta.

Órdenes de entrada: Stop y Limit

Por defecto, cuando salta la señal AniQuant entra a mercado, en la apertura de la barra siguiente. También puede entrar con una orden Stop o una orden Limit: la orden se coloca al cierre de la barra de la señal y espera al precio; si no llega en el tiempo que le das, caduca y no hay operación.

Stop: entrar si el precio confirma

Al comprar, el nivel va por encima (por ejemplo, el máximo de la vela de la señal): solo entras si el precio lo rompe. Al vender, por debajo. Es la entrada por rotura clásica.

Limit: entrar más barato

Al comprar, el nivel va por debajo (por ejemplo, el mínimo de la vela de la señal): solo entras si el precio retrocede hasta ahí. Al vender, por encima. Es la entrada en retroceso.

En el nivel de un indicador

La Stop o la Limit también se pueden colocar en el valor de un indicador en la barra de la señal, en vez de en un precio de la vela: una media, una banda, el máximo de N barras, la media anclada, un pivote o el mínimo de ayer… Con la misma distancia opcional (ticks, % o ATR), vigencia y rearme de siempre. Por ejemplo, comprar con una Limit en el S2 del pivote, o vender con una Stop bajo la media anclada.

  • Laboratorio: en la columna E/S, el papel Orden (solo en los indicadores que dan un precio). Cada nivel, con sus periodos, por cada tipo marcado (Stop, Limit) es una variante más del barrido.
  • AQ Génesis: en Configurar, debajo de la orden de entrada, las familias de nivel: la vela de la señal, pivotes, periodo anterior, máximo/mínimo de N barras, bandas y medias. Cada ronda toma uno con sentido: una Limit de compra en un soporte, una Stop de compra en una resistencia.
  • AQL: EntryOrder: limit at PivotS(2) valid 1 bars o EntryOrder: stop at Highest(High, 10) + 2 ticks.
  • El valor que se usa: el del indicador en la barra de la señal y fijo mientras la orden espera. En los pivotes y los niveles del periodo anterior, el de la barra siguiente: el pivote de mañana se calcula con el día de hoy, que ya ha terminado.
  • Exportar: en las seis plataformas. En diario el nivel es exacto; MetaTrader 5 lo es siempre. En las demás, con semanas, meses o sesiones intradía, en la última barra de cada periodo el código aún usa el nivel del anterior (al cierre no sabe que el periodo termina), y lo dice en un comentario.

Si el nivel queda al otro lado del precio (una Limit de compra por encima), se aplica la regla de nivel ya pasado de abajo. Sin valor (calentamiento del indicador), no se coloca.

En el Laboratorio

En la configuración del barrido, la fila Entrada tiene tres casillas: A mercado, Stop y Limit. Puedes marcar una, dos o las tres: cada una se prueba como una variante más del barrido (el contador de combinaciones se multiplica) y cada estrategia del ranking lleva la suya en el nombre, por ejemplo [Ord:Stop:X:1].

Sin tocar nada más, el Stop va en el extremo de la vela de la señal (rompe el máximo al comprar, el mínimo al vender) y el Limit en el extremo contrario, con 1 barra de vigencia. En ⚙ Avanzado se cambia todo: la referencia, la distancia, la vigencia y lo que hacer en los casos especiales (abajo). Stop y Limit van por la GPU, igual de rápido que a mercado.

Ese detalle de cada orden está en ⚙ Ajustes del barrido, siempre a la vista, con lo que significa cada opción.

En AQ Génesis

En ⚙️ Configurar, la fila Orden de entrada tiene las mismas casillas. Si marcas varias, Génesis las considera todas: cada ronda del genético prueba una, por turno, para que no compitan entre sí. Si marcas solo una, la usan todas las estrategias. Cada estrategia sellada lleva la suya (en el nombre y en su ficha) hasta el Portafolio, el Walk-Forward y los exports. La bitácora dice qué órdenes se turnan, y la búsqueda va por GPU.

En el lenguaje AQL

Una línea EntryOrder:. Sin ella, la estrategia entra a mercado como siempre.

EntryOrder: stop  high + 2 ticks          valid 1 bars
EntryOrder: limit close - 0.5 x ATR      valid 3 bars  rearm always
EntryOrder: stop  extreme                 valid 2 bars  ifcrossed skip
EntryOrder: market
Referencia y distancia

La referencia es un precio de la vela de la señal: extreme (máximo para comprar con stop, mínimo para comprar con limit; al revés al vender), high, low, close u open. La distancia, opcional, en ticks, en % o en x ATR (ATR de 14, el de Wilder). El signo lo marca el tipo: compra stop y venta limit, +; compra limit y venta stop, -. Revisar avisa si está al revés.

Vigencia y rearme

valid N bars: cuántas barras espera la orden (por defecto 1). Si mientras espera llega otra señal, rearm better (por defecto) la mueve al nivel nuevo solo si es mejor (más bajo para comprar, más alto para vender); rearm always siempre; rearm never, nunca. Al rearmar, la vigencia vuelve a empezar. Con vigencia 1 no hay rearme posible.

Nivel ya pasado

Si al colocarla el precio ya está al otro lado del nivel (una compra stop por debajo del cierre, por ejemplo): por defecto ifcrossed market, se entra igual (si la barra siguiente abre más allá, a la apertura), como haría un bróker; con ifcrossed skip la señal no genera operación.

touch: el limit que solo toca

Por defecto un limit solo se llena si el precio atraviesa el nivel un tick, como en AmiBroker, NinjaTrader, MultiCharts y TradingView: en la realidad, tocar el nivel no garantiza que te llenen. Con touch basta con tocarlo, que da resultados más optimistas.

Cómo se llena

Con hueco

Si la barra abre ya más allá del nivel, se entra a la apertura: el stop, a peor precio (como en la realidad); el limit, a mejor precio.

Dentro de la barra

Si el precio llega al nivel durante la barra, se entra al nivel, ajustado al tick en el sentido que hace la orden más difícil.

Deslizamiento

El stop desliza (al dispararse es una orden a mercado); el limit no (su riesgo no es deslizar, es no llenarse), igual que el take profit.

⚠️ La barra de llenado. Con barras OHLC no se sabe en qué orden se movió el precio dentro de la barra. Si la orden se llena dentro de la barra y en esa misma barra se alcanzan el TP o el SL, AniQuant supone lo peor (si caben los dos, gana el SL; en un limit, un máximo anterior al llenado no cobra el TP). Se marcan como ambiguas solo las dudosas de verdad: un Stop cuyo SL salta en la barra de llenado (el mínimo pudo ser anterior al llenado) y cualquier orden que toque TP y SL en esa barra. Un Limit que salta por el SL o un Stop que cobra el TP no lo son: para llegar ahí el precio pasa antes por el nivel de la orden. La Performance dice cuántas hay y cuánto suman, en la fila Operaciones ambiguas. Si pesan mucho, compruébalo con datos de menor marco temporal. Con datos de 1 minuto (Configuración → Dentro de la barra), AniQuant lo mira solo: ve si el mínimo fue antes o después del llenado, y la operación deja de ser ambigua.
✓ La Performance enseña junto al nombre la orden con que entra la estrategia (por ejemplo, Entrada: Stop máximo + 2 ticks, 1 barra). La orden forma parte de la estrategia: va en su huella, en el Portafolio, en el Walk-Forward y en todo lo demás.
➜ Exportar: AmiBroker replica el motor al céntimo; TradeStation/MultiCharts, MetaTrader 5, NinjaTrader 8, TradingView y ProRealTime traducen la misma lógica con sus órdenes stop y limit (el llenado dentro de la barra lo decide la plataforma). En TradingView el limit exige atravesar el nivel 1 tick, como AniQuant; en ProRealTime se llena con solo tocarlo, y el código lo avisa.
💡 Las estrategias que se dan la vuelta (entradas long y short a la vez) entran siempre a mercado.

El editor

Coloreado en vivo
Sintaxis resaltada token a token con la paleta de esta guía, gutter con números de línea y fuente monoespaciada.
Revisar
Valida contra el catálogo real de indicadores: lista los errores con línea y columna y resalta en amarillo la palabra exacta. Clic en un error → salta a esa línea.
Guardar / Abrir
Ficheros .aql (también abre los .aq antiguos) en C:\AniQuant\estrategias\, con el diálogo moderno de Windows, como el resto del programa.
▶
Probar

Backtest sobre el símbolo elegido y abre el Strategy Performance Report al instante.

📁
A Portafolio

La envía al Portafolio como estrategia concreta → re-test, equidad, Supervivencia, Multi-TF y PBO. Todo el pipeline.

🔬
A Testeo Masivo

Siembra los indicadores como filas de período fijo; el buscador reproduce la estrategia (y muchas más). Ensancha a rangos para optimizar alrededor.

🔓
Ida y vuelta

Y al revés: desde el Testeo Masivo o el Portafolio, clic derecho → Editar estrategia (AQL) abre cualquier estrategia como código editable. Descubres → editas → pruebas o reexportas.

Notas: el código describe una estrategia única (no rangos); both se interpreta como long; un or suelto entre dos condiciones se trata como and (para un OR, repite el bloque Entry: o ponlo entre paréntesis: (a or b)).

Más del editor

  • ·Al abrirse vacío trae una estrategia de ejemplo completa («Retroceso en tendencia»): pulsa Probar y se ejecuta tal cual. Bórrala y escribe la tuya.
  • ·Abre con el símbolo que tengas cargado en la ventana principal.
  • ·Exportar ▾ lleva a las seis plataformas: TradeStation/MultiCharts, AmiBroker, MetaTrader 5, ProRealTime, TradingView y NinjaTrader 8.
  • ·Admite números negativos: CCI(7) < -100, WilliamsR(14) > -20.
Pruébalo tú mismo

AniQuant se prueba gratis durante 14 días, con todos los módulos y sin tarjeta. Si tienes el libro, 30.

← Anterior
Costes de ejecución: comisión y deslizamiento
Siguiente →
Exportar estrategias a tu plataforma
Más en Construir estrategias